通达信导航家-主力成交量-指标公式（副图 源码 贴图）

莱因哈特

[通达信] 通达信导航家-主力成交量-指标公式（副图 源码 贴图）
VAR2:=HIGH-LOW;
VAR3:=ABS(OPEN-CLOSE);
VAR4:=HIGH-IF(CLOSE>OPEN,CLOSE,OPEN);
VAR5:=IF(CLOSE>OPEN,OPEN,CLOSE)-LOW;
VAR6:=VAR3/VAR2*VOL;
VAR7:=VAR4/VAR2*VOL;
VAR8:=VAR5/VAR2*VOL;
VAR9:=IF(VOL/CAPITAL>0.001,1,EXP(ABS(LOG(VOL/CAPITAL*100))));
VARA:=(CLOSE-MA(CLOSE,5))/MA(CLOSE,5)*100;
VARB:=MA(CLOSE,5)>MA(CLOSE,10) AND MA(CLOSE,10)>MA(CLOSE,30) AND MA(CLOSE,30)>MA(CLOSE,60);
VARC:=MA(CLOSE,5)<MA(CLOSE,10) AND MA(CLOSE,10)<MA(CLOSE,30);
{多头成交: }STICKLINE(CLOSE>MA(CLOSE,30),0,VOL,4,1),COLORRED;
{空头成交: }STICKLINE(CLOSE<MA(CLOSE,30),0,VOL,4,1),COLORGREEN;
{向上攻击量: }STICKLINE(VAR6>=VAR7 AND VAR6>=VAR8 AND CLOSE>OPEN,0,VAR6,4,0),COLORRED;
{向下攻击量: }STICKLINE(VAR6>=VAR7 AND VAR6>=VAR8 AND CLOSE<OPEN,0,VAR6,4,0),COLORGREEN;
{上探量: }STICKLINE(VAR7>VAR6 AND VAR7>VAR8,0,VAR7,4,0),COLORCCCC66;
{下探量: }STICKLINE(VAR8>VAR6 AND VAR8>VAR7,0,VAR8,4,0),COLORFF6633;
{相对地量:} STICKLINE(VAR9>2 AND VOL<MA(VOL,5)/2,0,VOL,2.5,0),COLORYELLOW;
DRAWTEXT(VAR9>2 AND VOL<MA(VOL,5)/2,VOL,'地量'),COLORYELLOW;
{放量: }STICKLINE(VOL>MA(VOL,5)*2.5,0,VOL,2.5,0),COLORWHITE;
DRAWTEXT(VAR7>VAR6 AND VARA>2 AND VAR7>VAR8 AND CLOSE>MA(CLOSE,5) AND CLOSE>MA(CLOSE,30) AND HIGH>MA(CLOSE,60) AND VOL>MA(VOL,5) AND VAR7>=MA(VOL,5),VOL,'逢高出货'),COLORGREEN;
DRAWTEXT(VAR8>VAR6 AND VAR8>VAR7 AND VARA<-2 AND CLOSE<MA(CLOSE,30) AND VAR8<MA(VOL,5)/2 AND MA(VOL,5)<MA(VOL,10),VOL,'逢低跟进'),COLORMAGENTA;
DRAWTEXT(VAR6>MA(VOL,5)*2 AND VAR6>=VAR7 AND VAR6>=VAR8 AND CLOSE>OPEN OR VOL>MA(VOL,5)*3 AND VARB,VOL,'强势参与'),COLORCC99CC;
DRAWTEXT(VAR6>=VAR7 AND VAR6>=VAR8 AND CLOSE<OPEN AND VAR6/VOL>0.7 AND VARC AND VAR6>MA(VOL,5),VAR6*2,'空头释放'),COLORGREEN;
V5:MA(VOL,5),COLORWHITE;
V10:MA(VOL,10),COLORGREEN;
V20:MA(VOL,20),COLORYELLOW;